For the latest version of JMP Help, visit JMP.com/help.


Publication date: 04/30/2021

New Window Example

The following example creates a window with multiple vertical and horizontal list boxes:

win = New Window( "New Window Example",
	<<Modal,
	<<ReturnResult, // ensure that you get the same result as with Dialog
	V List Box(
		V List Box(
			Text Box( "Radio Frequency Embolism Projection" ),
			Line Up Box(
				NCol( 2 ),
				Text Box( "Lower Spec Limit" ),
				lsl_box = Number Edit Box( 230 ),
				Text Box( "Upper Spec Limit" ),
				usl_box = Number Edit Box( 340 ),
				Text Box( "Threshold" ),
				threshold_box = Number Edit Box( 275 )
			),
			H List Box(
				Panel Box( "Type of Radio",
						rb_box1 = Radio Box( {"RCA", "Matsushita",
						"Zenith", "Sony"} )),
				Panel Box( "Type of Antenna" ,
						rb_box2 = Radio Box( {"Dish", "Helical", "Polarizing",
						"Radiant Array"} ) )
			),
			cb_box1 = Check Box( "Emission Synchronization" ),
			Text Box( "Title for plot" ),
			title_box = Text Edit Box( "My projection" ),
			H List Box( Text Box( "Quality" ),
			cb_box2 = Combo Box( {"Fealty", "Loyalty", "Piety", "Obsequiousness"} ) )
		),
		H List Box(
			Align( Right ),
			Spacer Box(),
			Button Box( "OK",
				lsl = lsl_box << Get;
				usl = usl_box << Get;
				threshold = threshold_box << Get;
				radio_type = rb_box1 << Get;
				antenna = rb_box2 << Get;
				synch = cb_box1 << Get;
				title = title_box << Get Text;
				quality = cb_box2 << Get;
			),
			Button Box( "Cancel" )
		)
	)
);
If(win["Button"] == 1,
 

// if the user clicks OK, show the selections in the log

	Show( "OK", lsl, usl, threshold, radio_type, antenna, synch, title, quality);
	,
	Show( "Canceled" ); // if the user clicked Cancel, print "Canceled"
);
Want more information? Have questions? Get answers in the JMP User Community (community.jmp.com).