行を追加するには、Add Rowsメッセージを送って行数を指定します。また、新しい行をどの行の後に挿入するかも指定できます。引数に指定できるのは、数値または数値を導き出す式のどちらかです。
dt << Add Rows( 3 ); // データテーブルの最後に3行追加する
dt << Add Rows( 3, 10 ); /* 10行目の後、11行目の前に3行追加する */
Add Rowsを利用すると、割り当てのリストを1つの引数として指定できます。割り当て式はカンマまたはセミコロンで区切ります。
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
dt << Add Rows(
{:名前 = "Peter", :年齢 = 14, :性別 = "M", :Name("身長(インチ)") = 61, :Name("体重(ポンド)") = 124}
);
または
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
dt << Add Rows(
{:名前 = "Peter"; :年齢 = 14; :性別 = "M"; :Name("身長(インチ)") = 61; :Name("体重(ポンド)") = 124}
);
複数の引数を指定して、複数のリストやリストのリストを送ることもできます。次のスクリプトは、さまざまな方法でAdd Rowsコマンドを使ってデータテーブルを作成します。
dt = New Table( "都市" );
dt << New Column( "xx", Numeric );
dt << New Column( "cc", Character, width( 12 ) );
dt << Add Rows( {xx = 12, cc = "シカゴ"} ); // 1つのリスト
dt << Add Rows( // 複数のリスト
{xx = 13, cc = "New York"}, {xx = 14, cc = "Newark"} );
dt << Add Rows( // リストのリスト
{{xx = 15, cc = "サンフランシスコ"}, {xx = Sqrt( 256 ), cc = "オークランド"}}
);
a = {xx = 20, cc = "マイアミ"};
dt << Add Rows( a ); // 1つのリストとして評価する
b={{xx = 17, cc = "サンアントニオ"},{xx = 18, cc = "ヒューストン"}, {xx = 19, cc = "ダラス"}};
dt << Add Rows( b ); // リストのリストとして評価する
メッセージで指定できる行の詳細については、行の属性を参照してください。