JMP Liveにある既存のレポートの内容を置き換えるには、そのレポートのパスまたはIDが必要です。JMP LiveでレポートIDを確認するには、そのレポートの投稿をクリックしてください。すると、投稿IDがURL内に表示されます。［詳細］からこのIDをコピーすることもできます。
既存のレポートを置き換えるときに、データをどのように更新するかを指定します。JMP Liveにある既存のデータをそのまま使用するか、JMP Liveにある既存のデータを更新するか、または、新しいデータテーブルを発行できます。
この例では、グラフビルダーのレポートおよびその元データを、JMP Liveの自分専用のスペースにあるフォルダに発行します。続けて、このレポートを新しいグラフビルダーのレポートで置き換えます。データは既存のものを使用します。
Names Default To Here(1);
// Big Classサンプルデータテーブルを開く。
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
/* グラフビルダーの2つのテーブルスクリプトを実行し、レポートへの参照をgbsmoother、gblineに格納する。 */
gbsmoother = dt << Run Script( "グラフビルダー 平滑線" );
gbline = dt << Run Script( "グラフビルダー 折れ線" );
// JMP Liveサーバーに接続する。
liveconnection = New JMP Live();
/* 自分専用のスペースにフォルダを作成し、タイトルと説明を指定する。確立したJMP Live接続を使い、jmpliveresultにJMP Live結果オブジェクトを戻す。 */
jmpliveresult = liveconnection << Create Folder( Parent folder( "~" ), Title( "Replace Example - Use Existing" ), If Exists( "use" ) );
// 結果からJMP Liveフォルダオブジェクトを取得する。
folder = jmpliveresult << As Scriptable;
// gbsmootherのレポートを含むcontentオブジェクトを作成する。
content = New JMP Live Content( gbsmoother, Title( "自分用の平滑線グラフ" ) );
// 新しく作成したフォルダにcontentを発行する。
jmpliveresult = liveconnection << Publish( content, Folder( folder ) );
// JMP Live結果オブジェクトから、発行済みの投稿のリストを取得する。
postlist = jmpliveresult << As Scriptable;
// 投稿の詳細を取得する。
bcPostId = "";
reportId = "";
For( i = 1, i <= postlist << Get Number Of Items, i += 1,
type = postlist[i] << Get Type();
If( type == "Data",
bcPostId = postlist[i] << Get ID
);
If( type == "Report",
reportId = postlist[i] << Get ID
);
);
// gblineのレポートを含むcontentオブジェクトを作成する。
content = New JMP Live Content( gbline, Title( "自分用の折れ線グラフ" ) );
// Replaceコマンドで、既存のデータを使用するように指定する。
jmpliveresult = liveconnection << Replace(
Report( reportID ),
content,
Use Existing Data( {{"Big Class", bcPostId}} )
);
// JMPのすべてのデータテーブルを保存せずに閉じる。
Close All( Data Tables, NoSave );
この例では、グラフビルダーのレポートおよびその元データを、JMP Liveの自分専用のスペースにあるフォルダに発行します。続けて、このレポートを新しいグラフビルダーのレポートで置き換え、既存のデータを更新します。
メモ: このデータを使用するJMP Liveの投稿がすべて更新されます。
Names Default To Here(1);
// Big Classサンプルデータテーブルを開く。
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
/* グラフビルダーの2つのテーブルスクリプトを実行し、レポートへの参照をgbsmoother、gblineに格納する。 */
gbsmoother = dt << Run Script( "グラフビルダー 平滑線" );
gbline = dt << Run Script( "グラフビルダー 折れ線" );
// JMP Liveサーバーに接続する。
liveconnection = New JMP Live();
/* 自分専用のスペースにフォルダを作成し、タイトルと説明を指定する。確立したJMP Live接続を使い、jmpliveresultにJMP Live結果オブジェクトを戻す。 */
jmpliveresult = liveconnection << Create Folder( Parent Folder( "~" ), Title( "Replace Example - Update Existing" ), If Exists( "use" ) );
// 結果からJMP Liveフォルダオブジェクトを取得する。
folder = jmpliveresult << As Scriptable;
// gbsmootherのレポートを含むcontentオブジェクトを作成する。
content = New JMP Live Content( gbsmoother, Title( "自分用の平滑線グラフ" ) );
// 新しく作成したフォルダにcontentを発行する。
jmpliveresult = liveconnection << Publish( content, Folder( folder ) );
// JMP Live結果オブジェクトから、発行済みの投稿のリストを取得する。
postlist = jmpliveresult << As Scriptable;
// 発行したレポート投稿およびデータ投稿のIDを取得する。
bcPostId = "";
reportId = "";
For( i = 1, i <= postlist << Get Number Of Items, i += 1,
type = postlist[i] << Get Type();
If( type == "Data",
bcPostId = postlist[i] << Get ID
);
If( type == "Report",
reportId = postlist[i] << Get ID
);
);
// gblineのレポートを含むcontentオブジェクトを作成する。
content = New JMP Live Content( gbline, Title( "自分用の折れ線グラフ" ) );
/* JMP Liveでgbsmootherレポートをgblineレポートで置き換える。既存のデータを更新するように指定する。 */
jmpliveresult = liveconnection << Replace(
Report( reportId ),
content,
Update Existing Data( {{"Big Class", bcPostId}} )
);
// JMPのすべてのデータテーブルを保存せずに閉じる。
Close All( Data Tables, NoSave );
この例では、グラフビルダーのレポートおよびその元データを、JMP Liveの自分専用のスペースにあるフォルダに発行します。続けて、このレポートを新しいグラフビルダーのレポートで置き換えます。新しいデータテーブルも発行し、新しいレポートで元データではなく、そちらのデータを使用するようにします。
Names Default To Here(1);
// Big Classサンプルデータテーブルを開く。
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
/* グラフビルダーの2つのテーブルスクリプトを実行し、レポートへの参照をgbsmoother、gblineに格納する。 */
gbsmoother = dt << Run Script( "グラフビルダー 平滑線" );
gbline = dt << Run Script( "グラフビルダー 折れ線" );
// JMP Liveサーバーに接続する。
liveconnection = New JMP Live();
/* 自分専用のスペースにフォルダを作成し、タイトルと説明を指定する。確立したJMP Live接続を使い、jmpliveresultにJMP Live結果オブジェクトを戻す。 */
jmpliveresult = liveconnection << Create Folder( Parent Folder( "~" ), Title( "Replace Example - Publish New" ), If Exists( "use" ) );
// 結果からJMP Liveフォルダオブジェクトを取得する。
folder = jmpliveresult << As Scriptable;
// gbsmootherのレポートを含むcontentオブジェクトを作成する。
content = New JMP Live Content( gbsmoother, Title( "自分用の平滑線グラフ" ) );
// 新しく作成したフォルダにcontentを発行する。
jmpliveresult = liveconnection << Publish( content, Folder( folder) );
// gblineのレポートを含むcontentオブジェクトを作成する。
content = New JMP Live Content( gbline, Title( "自分用の折れ線グラフ" ) );
/* JMP Liveでgbsmootherレポートをgblineレポートで置き換える。置き換え対象のレポートをパスで指定し、新しいデータを発行する。*/
jmpliveresult = liveconnection << Replace(
Report( "~/Replace Example - Publish New/自分用の平滑線グラフ" ),
Content,
Publish New Data( {"Big Class"} )
);
// JMPのすべてのデータテーブルを保存せずに閉じる。
Close All( Data Tables, NoSave );