ホバーラベルの実行コンテキストの操作

ホバーラベルの実行コンテキスト変数は、グラフレットスクリプトやテキストレットスクリプトの実行環境を定義します。

ローカルデータフィルタ

グラフレットを定義する作業は、データをどのようなグラフにしてサムネールとして表示するかを定義する作業です。しかし、どの行を表示するかは、どうすれば指定できるのでしょうか。

このような情報は、ユーザが基本となるグラフ（グラフレットの定義の追加先であるグラフ）のどの要素にポインタを置くかによって、間接的に指定されます。たとえば、基本のグラフが棒グラフだとしましょう。いずれかの棒にポインタを置くと、その棒に対応するすべての行がグラフに含められます。そうして作成されたグラフがサムネールとしてホバーラベルに表示されるようになります。つまり、ホバーしたグラフ要素が、グラフの作成に使うデータコンテキストとなります。

このデータコンテキストは、Where節として表現され、次のものに従って計算されます。

• 基本のグラフで使用されているグラフの種類

• 基本のグラフの各役割が割り当てられている列

• 調べている特定のグラフ要素の現在の値

生成されたWhere節を使ってローカルデータフィルタが作成され、それがグラフレットの定義で指定されているプラットフォームに適用されます。

ローカルデータフィルタの作成に使うソースとして、次のようなグラフの役割が使用できます。

• X（入れ子状の列を含む）

• Y（要約統計量などの計算でないもの）

• 重ね合わせ

数値列は、基本のグラフの種類によって、1つの値との比較に使用されるか、ある範囲に含まれるかどうかを確認されます。ヒストグラムやヒートマップ（さらには箱ひげ図の箱）のように、数値データを棒に分けるグラフは、Where節の該当する範囲を使用します。

基本のグラフに関連付けられているローカルデータフィルタのWhere節も取得されます。

ローカルスコープコンテキスト

グラフレットや他のホバーラベル拡張機能（テキストレットのSetup、グリッドレットのAppendおよびClickスクリプトなど）の属性を構成するJSL式。この名前空間は、実行コンテキストの情報（ホバーラベルのグリッドエントリ、基本のグラフ要素への参照、関連するデータ）を示すローカル変数で初期化されます。これらの変数は、グラフレットプリセットによって頻繁に使用されます。

図12.4に、グラフレットのローカル名前空間に用意されている変数を示します。詳細については、ホバーラベルの実行コンテキスト変数の全体例を参照してください。

注: 変数の使用例を見るには、グラフを右クリックし、［ホバーラベルエディタ］を選択し、［グラフレット］パネルを選択して、いずれかのプリセットを選択します。「イメージ」フィールドに表示されるコードは、いくつのホバーラベル実行コンテキスト変数を使ってグラフレットの動作が制御されるかを示します。

{"_mode", "Textlet"},

	If( local:_mode == "Picture",

		local:sizeDef = "Size( 200, 250 ),";

		local:l = 0;

	,

		local:sizeDef = "";

		local:l = 1;

	);

{"_groupings", {:性別}}

{"_measurements", {:Name("身長(インチ)}

{"_filters", {:性別}}

expr = Parse( local:_where );

r = local:_dataTable << Get Rows Where( expr );

ss = dt << Subset( Private, Invisible, Rows( r ) );

Summarize( ss, exg = By( :sex ), exm = Mean( :height ) );

{"_where", ":性別 == \!"F\!""}

local:_h = Round(Mean( :Name("身長(インチ)")[local:_dataTable << Get Rows Where( local:_whereExpr )] ), 2);

{"_whereExpr", :性別== "F"}

Title( || local:_displaySegName ||

       "のグラフレット、深さは " || Char( local:_drillDepth ))

{"_displaySegName", "BarSeg"}

{"_dataTable", Data Table( "Big Class" )}

{"_summaryStatistic", "Mean"}

{"_drillDepth", 1}

{"_firstRow", 1}

{"_underlyingRows", 18}

これらの変数に加え、ホバーラベルの各グリッドエントリに対して変数が1つ定義されます。この変数の名前の先頭に「_」を付けたものが、グリッドエントリの名前になります。

注: これらの変数の例については、散布図行列と楕円のコンテキストを定義する例を参照してください。

ホバーラベル実行コンテキスト変数を使う例として、散布図行列を作成し、ある点にポインタを置くと楕円の拡大画像が表示され、その楕円をクリックするとグラフビルダーが開いてその楕円に変更を加えられるようにすることができます。グラフレットには、基本の散布図行列のセルにあるのと同じグラフ（そのセルに関連付けられている2つの列の散布図）が表示されます。

サムネールをクリックすると、行列からそのセルを「抽出」するような形になり、そのセルが独立したグラフとして表示されます。

散布図行列と楕円のコンテキストを定義する例のスクリプトを使うと、メインの散布図行列からセルを抽出することができます。

図12.49 散布図行列で楕円を表示する 

散布図行列と楕円のコンテキストを定義する例

次のスクリプトは、スクリプトの実行コンテキストを使用した例です。このスクリプトは、図12.49に表示されている散布図行列を作成します。

Names Default To Here( 1 );

dt = Open( "$SAMPLE_DATA/Solubility.jmp" );

win = New Window( "Scatterplot Matrix Graphlet Example",

	plt = dt << Multivariate(

		Y(

			:Name( "1-オクタノール" ),

			:エーテル,

			:クロロフォルム,

			:ベンゼン,

			:四塩化炭素,

			:ヘキサン

		),

		Estimation Method( "Row-wise" ),

		Scatterplot Matrix(

			Density Ellipses( 1 ),

			Shaded Ellipses( 1 ),

			Ellipse Color( 69 )

			Horizontal( 1 )

		)

	)

);

frame = win << xpath( "//FrameBox" );

frame << Set Graphlet(

	Picture(

		Show( local:_displaySegName );

		If( local:_displaySegName == "MarkerSeg",

			// 散布図のセル

			Graph Builder(

				Size( 400, 200 ),

				Show Control Panel( 0 ),

				Show Legend( 0 ),

				Variables(

					X( local:_groupings[1] ),

					Y( local:_groupings[2] )

				),

				Elements( Points( X, Y ), Ellipse( X, Y ) )

			),

			// 行列の対角に他のヒストグラム

			If( local:_N > 5, /* メモ: メインのグラフが

				ヒストグラムである場合のみ存在する */

				Graph Builder(

					Size( 400, 400 ),

					Show Control Panel( 0 ),

					Show Legend( 0 ),

					Variables( X( local:_groupings[1] ) ),

					Elements( Histogram( X ) )

				),

				Graph Builder(

					Size( 400, 400 ),

					Show Control Panel( 0 ),

					Show Legend( 0 ),

					Variables( X( local:_groupings[1] ) ),

					Elements( Points( X ) )

				)

			)

		);

	),

	// ドリルダウンの最初のレベル（メインのグラフ）でフィルタをスキップする

	SkipFilters( local:_drillDepth == 1 ), // リストなし、つまりすべてのフィルタ

	Title( "Graphlet" ),

	Reapply( local:_displaySegName == "HistSeg" & local:_N > 5 )

);

ホバーラベルの実行コンテキスト変数の全体例

図12.50のグラフは、次のようなスクリプトで作成します。棒の上にポインタを置くと、ホバーラベルが表示されます。データの詳細やホバーラベル実行コンテキスト変数がログに表示されます。

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

dt << Graph Builder(

	Size( 528, 450 ),

	Show Control Panel( 0 ),

	Variables( X( :sex ), Y( :Name("身長(インチ)") ) ),

	Elements( Bar( X, Y, Legend( 3 ) ) ),

	SendToReport(

		Dispatch(

			{},

			"Graph Builder",

			FrameBox,

			{Set Textlet(

				Setup(

					local:encodedWhere = XML Encode( local:_where );

					/* Show()は、ログにあるHLEC変数の

					詳細を表示する */

					Show( Namespace( "local" ) << Get Contents() );

				),

				Markup(

					"

<b>Groupings</b>:{local:_groupings}

<b>Measurements</b>:{local:_measurements}

<b>Summary statistic</b>:{local:_summaryStatistic}

<b>Filter columns</b>:{local:_filters}

<b>Where clause</b>:{local:encodedWhere}

<b>Graph type</b>:{local:_displaySegName}

<b>Data table</b> {local:_dataTable}

<b>Drill depth</b>:{local:_drillDepth}

<b>First Row</b>:{local:_firstRow}

<b>Underlying Rows</b>:{local:_underlyingRows}

"

				)

			)}

		)

	)

);

図12.50 棒グラフのテキストレット